/*
 processing でビュホンの針を描く
 <Time-stamp: <2019-04-09 11:29:07 nakata>
 */

//初期パラメータの指定
int sq_size = 400; // 正方形のサイズ
int output_size = 100; // 文字出力のサイズ
int d = 50; // 平行線の幅
int l = 50; // 針の長さ (l≦d)
int step = 100; // 針の本数
int mergin = int(d/sqrt(2)); // マージンの幅を平行線から計算（キャスト）
int alcnt = 0; // 全てのカウント
int crcnt = 0; // 交わった針のカウント
int lchk =0; // マウスで開始と停止をチェックするため

/*
void settings() {
  size(sq_size, sq_size+output_size);
}
*/

void setup() {
  size(400, 500);
//  smooth(); // 滑らかな描画のおまじない（処理は遅くなる）
  background(#373BED);
  int i;
  // y座標がd間隔で平行線を引く
  for (i=d; i<sq_size; i += d) {
    stroke(#FFFFFF);  //輪郭線の色を指定
    line(0, i, sq_size, i);
  }


  //文字のサイズ
  textSize(20);
  //色の指定
  fill(#EB0FF0);
  text("Buffon needle (approx. Pi)", d, sq_size+output_size/2);
  //色の指定
  fill(#56AA5F);
//  text("Press 's' stop, Press 'c' continue", d, sq_size+int(output_size*0.75));
  text("Press Left mouse button (start/stop)", d, sq_size+int(output_size*0.75));
  noLoop();// draw()を実行しない
}

void mousePressed(){// マウスを奇数回押せば開始、偶数回で停止
  if (lchk%2 == 0)
    loop();
  else
    noLoop();
  lchk++;
}


void draw() { 
  // 針を落とす
  //針の中心(mergin,mergin)..(sq_size-mergin,(sq_size-mergin)の乱数
  //角度0..PI
  float center_x = random(mergin, sq_size-mergin);
  float center_y = random(mergin, sq_size-mergin);
  float theta = random(0, PI);
  
  int ncenter_x = int(center_x+0.5);
  int ncenter_y = int(center_y+0.5);
  
  int sx = int(center_x+l/2*cos(theta)+0.5);
  int sy = int(center_y-l/2*sin(theta)+0.5);
  int tx = int(center_x+l/2*cos(theta+PI)+0.5);
  int ty = int(center_y-l/2*sin(theta+PI)+0.5);

//  int dist = ncenter_y %d;// 平行線からの距離
  float fdist= center_y;
  while(fdist > d)
    fdist = fdist - d;
  
  alcnt ++;
  if( fdist > d/2)
    fdist = d - fdist;
  if(l*sin(theta)/2 > fdist){
    crcnt ++;
    stroke(255, 0, 0);  //赤色
  }else
    stroke(0, 255, 0);  //青色
    
  line(sx, sy, tx, ty);

//  コンソールエリアの数値の出力
//  println(alcnt,"(cross)", crcnt,  "Pi approx.", 2*l*alcnt/(float(crcnt)*d));
  println(alcnt);
  println(2*l*alcnt/(float(crcnt)*d));


}


// キーを押したときの処理
void keyPressed() {
  if ( key == 's' ) 
    noLoop();      // 停止
  if ( key == 'c' ) 
    loop();        // 再開
}